CV triggers to MIDI

sleeptotem
New Member

Posts: 48

CV triggers to MIDI Feb 4, 2021 21:51:28 GMT admin, bert, and 2 more like this

Quote

Post by sleeptotem on Feb 4, 2021 21:51:28 GMT

Hello,
Here is my second DIY project using the Teensy 4.0.

Features:
- 7 cv ins
- 8 buttons (Red button is a mode button the other 7 are for notes/mutes)
- 1 Clickable encoder
- 128x32 oled screen which displays relevant information
- Two modes, NoteS and MUTES
- 8 selectable scales (Mayor, Doric, Frigian, Lydian, Mixolydian, Aeolian, Locrian, Augmented)
- Can change key to any of the 12 chromatic notes
- Can change octave from -2 to 6
- Can adjust note probability from 0 -100
- Each midi channel has its own mutes states, scale, octave, key and note probability.
- Each cv in triggers a note of
- Holding the red button and pressing one of the 7 main buttons changes the current midi channel
- Holding the red button and moving the encoder changes the selected scale
- Clicking the encoder will mute/unmute all notes in the current channel
- In NoteS mode each of the 7 main buttons triggers one of the notes
- In NoteS mode moving the encoder will increase/decrease the current key
- In MUTES mode each of the 7 main buttons toggles the notes mute state
- In MUTES mode moving the encoder will increase/decrease the octave
- Holding one of the 7 main buttons a moving the encoder will increase/decrease note probability (can change multiple at once)
- Can send notes up to 7 midi channels (on inital load all channels are muted except for channel 1)

In the future I would like store settings on the EPPROM so you can save your changes.

Heres a video showing how it integrates with the deluge

And heres the code, any questions/feedback let me know

#include <MIDI.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 32 // OLED display height, in pixels
#define SCREEN_ADDRESS 0x3C ///< See datasheet for Address; 0x3D for 128x64, 0x3C for 128x32
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT);

MIDI_CREATE_INSTANCE(HardwareSerial, Serial1, MIDI);
const int SERIAL_DATA_WIDTH     = 8;
const int PULSE_WIDTH_USEC      = 5;
const int ploadPin              = 10;  // Connects to Parallel load pin the 165
const int dataPin               = 12; // Connects to the Q7 pin the 165
const int clockPin              = 11; // Connects to the Clock pin the 165
const int noteVelocity          = 100;
const int encoderSW             = 7; 
const int encoderDT             = 8;
const int encoderCLK            = 9; 
const int cvIns[8]              = { A0, A1, A2, A3, A6, A7, A8, A9 };
const long holdThreshold        = 7000;
const int notes[8][7] = { 
  { 0, 2, 4, 5, 7, 9, 11 }, /// Jonica
  { 0, 2, 3, 5, 7, 9, 10 }, /// Dorica
  { 0, 1, 3, 5, 7, 8, 10 }, /// Frigia
  { 0, 2, 4, 6, 7, 9, 11 }, /// Lidia
  { 0, 2, 4, 5, 7, 9, 10 }, /// Mixo
  { 0, 2, 3, 5, 7, 9, 10 }, /// Eolica
  { 0, 1, 3, 5, 6, 8, 10 }, /// Locria
  { 0, 2, 4, 6, 8, 10, 11 }, /// Aumentada
};
int midiChannel = 1;
int currentMode = 1;
long modeButtonTimer = 0;
unsigned long buttonTimers[8] = { 0, 0, 0, 0, 0, 0, 0, 0 };
unsigned int muteStates[7][7] = {
  { 0, 0, 0, 0, 0, 0, 0 },
  { 1, 1, 1, 1, 1, 1, 1 },
  { 1, 1, 1, 1, 1, 1, 1 },
  { 1, 1, 1, 1, 1, 1, 1 },
  { 1, 1, 1, 1, 1, 1, 1 },
  { 1, 1, 1, 1, 1, 1, 1 },
  { 1, 1, 1, 1, 1, 1, 1 }
};
unsigned int noteProbabilities[7][7] = {
  { 100, 100, 100, 100, 100, 100, 100 },
  { 100, 100, 100, 100, 100, 100, 100 },
  { 100, 100, 100, 100, 100, 100, 100 },
  { 100, 100, 100, 100, 100, 100, 100 },
  { 100, 100, 100, 100, 100, 100, 100 },
  { 100, 100, 100, 100, 100, 100, 100 },
  { 100, 100, 100, 100, 100, 100, 100 }
};
int cvStates[8]                 = { 0, 0, 0, 0, 0, 0, 0, 0  };
int cvPrevStates[8]             = { 0, 0, 0, 0, 0, 0, 0, 0 };
int noteKeyCounters[7]          = { 0, 0, 0, 0, 0, 0, 0 }; 
int octaveCounters[7]           = { 10, 10, 10, 10, 10, 10, 10 }; 
int scaleCounters[7]            = { 0, 0, 0, 0, 0, 0, 0 }; 
int octaves[7]                  = { 5, 5, 5, 5, 5, 5, 5 }; 
int noteKeys[7]                 = { 0, 0, 0, 0, 0, 0, 0 }; 
int scales[7]                   = { 0, 0, 0, 0, 0, 0, 0 }; 
int cvControlModes[7]           = { 0, 0, 0, 0, 0, 0, 0 };
int midiChannelIndex            = midiChannel - 1;
int currentScale                = scales[midiChannelIndex];
int currentOctave               = octaves[midiChannelIndex];
int currentNoteKey              = noteKeys[midiChannelIndex];
boolean isScreenRefreshing      = false;
boolean shouldRefreshScreen     = true;
int encoderState;
int encoderLastState;
int encoderSWState;
int encoderSWLastState;
unsigned int pinValues;
unsigned int oldPinValues;


void updateSelectedModes() {
  midiChannelIndex = midiChannel - 1;
  currentScale = scales[midiChannelIndex];
  currentOctave = octaves[midiChannelIndex];
  currentNoteKey = noteKeys[midiChannelIndex];
}

void readCvIns() {
  updateSelectedModes();
  for(int i = 0; i <= 7; i++){
    cvStates[i] = digitalRead(cvIns[i]); 
    if(cvStates[i] != cvPrevStates[i]) {
      if(cvStates[i] == 1){
        for(int j = 0; j < 7; j++) {
          if(!muteStates[j][i]) {
            int chanceToPlay = noteProbabilities[j][i] == 100 ? 1 : random(0, 100) <= noteProbabilities[j][i];    
            
            if(chanceToPlay == 1 && noteProbabilities[midiChannelIndex][i] != 0){
              int cvNote = notes[scales[j]][i] + (octaves[j] * 12) + noteKeys[j];
              MIDI.sendNoteOn(cvNote, noteVelocity, j+1);
              MIDI.sendNoteOff(cvNote, 0, j + 1);
            }
          }
        }
      } 
      cvPrevStates[i] = cvStates[i];
    }
  }
}

void readEncoder() { 
  encoderState = digitalRead(encoderCLK);
  encoderSWState = digitalRead(encoderSW);
  if (encoderState != encoderLastState){     
    boolean isButtonHeld = false;
    
    if (digitalRead(encoderDT) != encoderState) {
        for(int i = 0; i < 8; i++){
         if((pinValues >> i) & 1){
            isButtonHeld = true;
            if(i == 0 && scaleCounters[midiChannelIndex] > 0) scaleCounters[midiChannelIndex]--; 
            if(i != 0 && noteProbabilities[midiChannelIndex][i-1] > 0) noteProbabilities[midiChannelIndex][i-1]--;
          }
        }
        if(!isButtonHeld) {
          if(currentMode){
            if(octaveCounters[midiChannelIndex] > 0) octaveCounters[midiChannelIndex]--;
          }else{
            if(noteKeyCounters[midiChannelIndex] > 0) noteKeyCounters[midiChannelIndex]--;
          }
        }      
    } else {
      for(int i = 0; i < 8; i++){
         if((pinValues >> i) & 1){
            isButtonHeld = true;
            if(i == 0 && scaleCounters[midiChannelIndex] < 14) scaleCounters[midiChannelIndex]++; 
            if(i != 0 && noteProbabilities[midiChannelIndex][i-1] < 100) noteProbabilities[midiChannelIndex][i-1]++;
          }
        }
      if(!isButtonHeld){
        if(currentMode){
          if(octaveCounters[midiChannelIndex] < 16) octaveCounters[midiChannelIndex]++;
        }else{
          if(noteKeyCounters[midiChannelIndex] < 22) noteKeyCounters[midiChannelIndex]++;
        }
      }
    }
    octaves[midiChannelIndex] = round(octaveCounters[midiChannelIndex]/2);
    noteKeys[midiChannelIndex] = round(noteKeyCounters[midiChannelIndex]/2);
    scales[midiChannelIndex] = round(scaleCounters[midiChannelIndex]/2);    
    encoderLastState = encoderState;
    shouldRefreshScreen = true;
  }
  if(encoderSWState != encoderSWLastState) {
    if(!encoderSWState){
      for(int i = 0; i < 8; i++){
        muteStates[midiChannelIndex][i - 1] = !muteStates[midiChannelIndex][i - 1];
      }
    }
    encoderSWLastState = encoderSWState;
    shouldRefreshScreen = true;
  }
}

void readShiftRegisters() {
  long bitVal;
  unsigned int bytesVal = 0;
  digitalWrite(ploadPin, LOW);
  delayMicroseconds(PULSE_WIDTH_USEC);
  digitalWrite(ploadPin, HIGH);

  for (int i = 0; i < SERIAL_DATA_WIDTH; i++) {
    bitVal = digitalRead(dataPin);
    bytesVal |= (bitVal << ((SERIAL_DATA_WIDTH-1) - i));
    if((oldPinValues >> i) & 1) buttonTimers[i]++;
    digitalWrite(clockPin, HIGH);
    delayMicroseconds(PULSE_WIDTH_USEC);
    digitalWrite(clockPin, LOW);
  }
  pinValues = bytesVal;
  delayMicroseconds(PULSE_WIDTH_USEC);
}

void triggerButtonActions() {
  updateSelectedModes();
  for(int i = 0; i < SERIAL_DATA_WIDTH; i++) {
    int currentPin = (pinValues >> i) & 1;
    int previousPin = (oldPinValues >> i) & 1;
    if(currentPin != previousPin){
      if (currentPin){
        if(i != 0) {
          if((pinValues >> 0) & 1){
            if(i <= 7) midiChannel = i;
            midiChannelIndex = midiChannel -1;
            shouldRefreshScreen = true;
          } else {
            if(currentMode == 0) {
              int note = notes[currentScale][i-1] + (currentOctave * 12) + currentNoteKey;
              MIDI.sendNoteOn(note, noteVelocity, midiChannel);
              MIDI.sendNoteOff(note, 0, midiChannel);
            }
          }
        }
      } else {
        if(i == 0){
          if(buttonTimers[i] < holdThreshold) currentMode = !currentMode;  
        } else {
          if(currentMode == 1 && buttonTimers[0] == 0  && buttonTimers[i] < holdThreshold) {
            muteStates[midiChannelIndex][i - 1] = !muteStates[midiChannelIndex][i - 1];
          }
        }
        buttonTimers[i] = 0;
        shouldRefreshScreen = true;
      }
    }
  }
}

void refreshScreen() {
  isScreenRefreshing = true;
  display.clearDisplay();
  
  for(int i = 0; i < 8; i++) {
    if (i == 0) {
      display.setCursor(0, 2);
      switch(currentNoteKey) {
        case 1:
          display.print("C#");
          break;
        case 2:
          display.print("D");
          break;
        case 3:
          display.print("D#");
          break;
        case 4:
          display.print("E");
          break;
        case 5:
          display.print("F");
          break;
        case 6:
          display.print("F#");
          break;
        case 7:
          display.print("G");
          break;
        case 8:
          display.print("G#");
          break;
        case 9:
          display.print("A");
          break;
        case 10:
          display.print("A#");
          break;
        case 11:
          display.print("B");
          break;
        default:
          display.print("C");
          break;  
      }
      int octaveHorizontal = currentOctave < 2 ? 18 : 24;
      display.setCursor(octaveHorizontal, 2);
      display.print(currentOctave - 2);
      display.setCursor(0, 13);
      switch(currentScale) {
        case 1:
          display.print("Dor");
          break;
        case 2:
          display.print("Fri");
          break;
        case 3:
          display.print("LID");
          break;
        case 4:
          display.print("MIX");
          break;
        case 5:
          display.print("Eol");
          break;
        case 6:
          display.print("dim");
          break;
        case 7:
          display.print("AUG");
          break;
        default:
          display.print("MAY");
          break;  
      }
      display.setCursor(24, 13);
      display.print(midiChannel);
      display.setCursor(0, 23);
      currentMode == 0 ?  display.print("NoteS") : display.print("MUTES");
    } else {
      int vAlign = (i * 13) + 23;
      display.setCursor(12, vAlign);
      if(buttonTimers[i] > holdThreshold) {
        display.print(round(noteProbabilities[midiChannelIndex][i - 1]));
      } else {
        muteStates[midiChannelIndex][i - 1] == 1 ?  display.print("X") : display.print("O");
      }
    }
  }
  display.display();
  isScreenRefreshing = false;
  shouldRefreshScreen = false;
}

void setup() {
  Serial.begin(115200);
  MIDI.begin(); 
  display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS);
  delay(100);
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setRotation(3);
  pinMode (encoderCLK,INPUT);
  pinMode (encoderDT,INPUT);
  pinMode(dataPin, INPUT);
  pinMode(ploadPin, OUTPUT);
  pinMode(clockPin, OUTPUT);
  digitalWrite(clockPin, LOW);
  digitalWrite(ploadPin, HIGH);
  for(int i = 0; i < 7; i++) {
    pinMode(cvIns[i], INPUT);
    attachInterrupt(digitalPinToInterrupt(cvIns[i]), readCvIns, CHANGE);
  }
  readShiftRegisters();
  oldPinValues = pinValues;
}

void loop() {
  readShiftRegisters();
  readEncoder();
  triggerButtonActions();
  oldPinValues = pinValues;  
  if(shouldRefreshScreen && !isScreenRefreshing) refreshScreen();
}

Last Edit: Feb 10, 2021 12:53:19 GMT by sleeptotem

cpruby Junior Member Posts: 73	CV triggers to MIDI Feb 5, 2021 3:31:20 GMT Quote Select Post Deselect Post Link to Post Back to Top Post by cpruby on Feb 5, 2021 3:31:20 GMT This project quickly went from "I think I can try that" to "whoa." What form factor is this eventually going to end up as? Will you try to fit it into a module? Will it be in its own enclosure?

pt3r
Admin Member

Counter culture is the R&D of capitalism...

Posts: 2,204

CV triggers to MIDI Feb 5, 2021 7:47:19 GMT laenan likes this

Quote

Post by pt3r on Feb 5, 2021 7:47:19 GMT

Looking good, but I would like to point out that using the delay function is not ideal if you are dealing with events that can happen in parallel i.e. the user can operate different buttons at the same time thus launching triggers at the same time.

Delay will effectively stop every other activity until the specified delay has passed, thus turning parrellel triggers into a sequence of triggers.

Have a look at the arduino Digital tutorial BlinkWithoutDelay, this will show you in the how to implement pauses without 'blocking' the processor.

deofol.bandcamp.com
soundcloud.com/deofol
www.youtube.com/user/pt3r

sleeptotem
New Member

Posts: 48

CV triggers to MIDI Feb 5, 2021 8:49:13 GMT

Quote

Post by sleeptotem on Feb 5, 2021 8:49:13 GMT

Feb 5, 2021 7:47:19 GMT pt3r said:

Looking good, but I would like to point out that using the delay function is not ideal if you are dealing with events that can happen in parallel i.e. the user can operate different buttons at the same time thus launching triggers at the same time.

Delay will effectively stop every other activity until the specified delay has passed, thus turning parrellel triggers into a sequence of triggers.

Have a look at the arduino Digital tutorial BlinkWithoutDelay, this will show you in the how to implement pauses without 'blocking' the processor.

Ahh yes ty for the example. Ill modify my code to remove the delay bit.

sleeptotem
New Member

Posts: 48

CV triggers to MIDI Feb 5, 2021 8:58:18 GMT

Quote

Post by sleeptotem on Feb 5, 2021 8:58:18 GMT

Feb 5, 2021 3:31:20 GMT cpruby said:

This project quickly went from "I think I can try that" to "whoa." What form factor is this eventually going to end up as? Will you try to fit it into a module? Will it be in its own enclosure?

I would love to fit it into a module but my hardware skills are way worse than my programming so im not sure if ill ever be able to make it into an enclosure or a module.
But yes, ideally I would like it to be its own little 1U module with a similar setup as it is now so 7 buttons arranged in whatever way the space allows for plus a tiny oled screen to display all the parameters.

I was thinking of adding a control to change the scale and key but ill have to think about that one since I dont want to add anymore buttons.

Last Edit: Feb 5, 2021 9:03:07 GMT by sleeptotem

sleeptotem
New Member

Posts: 48

CV triggers to MIDI Feb 10, 2021 12:45:03 GMT keurslagerkurt likes this

Quote

Post by sleeptotem on Feb 10, 2021 12:45:03 GMT

Just updated the main post with some changes/improvements I made:

- Added oled screen to display settings
- Added an encoder
- Increased cv ins from 6 to 7
- Can select from 8 scales
- Can change root note
- Can change octave
- Can change not probability

Let me know what you think!

Last Edit: Feb 10, 2021 12:53:46 GMT by sleeptotem

rodney
Admin Member

must fix that website ...

Posts: 609

CV triggers to MIDI Feb 11, 2021 21:44:52 GMT

Quote

Post by rodney on Feb 11, 2021 21:44:52 GMT

Feb 5, 2021 8:49:13 GMT sleeptotem said:

Feb 5, 2021 7:47:19 GMT pt3r said:

Looking good, but I would like to point out that using the delay function is not ideal if you are dealing with events that can happen in parallel i.e. the user can operate different buttons at the same time thus launching triggers at the same time.

Delay will effectively stop every other activity until the specified delay has passed, thus turning parrellel triggers into a sequence of triggers.

Have a look at the arduino Digital tutorial BlinkWithoutDelay, this will show you in the how to implement pauses without 'blocking' the processor.

Ahh yes ty for the example. Ill modify my code to remove the delay bit.

Also, the Teensy has some cool timing stuff built-in so you can over/under-clock it and milliseconds will still be milliseconds when you run your code.

I should probably be asleep

zaphodb
New Member

Posts: 7

CV triggers to MIDI Feb 14, 2021 15:16:35 GMT

Quote

Post by zaphodb on Feb 14, 2021 15:16:35 GMT

Nice project!

Just a suggestion, code like the 2 switch statements can be shortened quite a bit by putting the case values in a table and using an index to choose the values. E.g. the first switch statement:

 for(int i = 0; i < 8; i++) {
    if (i == 0) {
      display.setCursor(0, 2);
      switch(currentNoteKey) {
        case 1:
          display.print("C#");
          break;
        case 2:
          display.print("D");
          break;
        case 3:
          display.print("D#");
          break;
// etc etc

could be shortened by using the currentNotKey as an index to an array of note values ("A", "B" etc).


String NoteValue[] = { "A", "B", "C", "C#" }; // etc etc
for(int i = 0; i < 8; i++) {
    if (i == 0) {
      display.setCursor(0, 2);
      display.print(NoteValue[currentNoteKey]);
    }
    // rest of your code

Whatever the currentNoteKey value is, the correct NoteValue will be printed. Obviously you need to align the values in the array with the values currentNoteKey can get.

Similarly the next switch statement

      switch(currentScale) {
        case 1:
          display.print("Dor");
          break;
        case 2:
          display.print("Fri");
          break;
        case 3:
          display.print("LID");
          break;
        case 4:
          display.print("MIX");
          break;
        case 5:
        // etc etc

can be reduced to:

 
String ScaleValue[] = { "Dor", "Fri", "LID" }; // etc etc.
for(int i = 0; i < 8; i++) {
      // 
      display.print(ScaleValue[currentScale]);
      // rest of your code

I see that you are not using an interrupt to decode the rotary movement. Checking the encoder in the main loop is fast enough or do you experience that sometimes clicks are missed?

Last Edit: Feb 14, 2021 15:19:50 GMT by zaphodb

sleeptotem
New Member

Posts: 48

CV triggers to MIDI Feb 16, 2021 9:30:28 GMT

Quote

Post by sleeptotem on Feb 16, 2021 9:30:28 GMT

Feb 14, 2021 15:16:35 GMT zaphodb said:

Nice project!

Just a suggestion, code like the 2 switch statements can be shortened quite a bit by putting the case values in a table and using an index to choose the values. E.g. the first switch statement:

 for(int i = 0; i < 8; i++) {
    if (i == 0) {
      display.setCursor(0, 2);
      switch(currentNoteKey) {
        case 1:
          display.print("C#");
          break;
        case 2:
          display.print("D");
          break;
        case 3:
          display.print("D#");
          break;
// etc etc

could be shortened by using the currentNotKey as an index to an array of note values ("A", "B" etc).


String NoteValue[] = { "A", "B", "C", "C#" }; // etc etc
for(int i = 0; i < 8; i++) {
    if (i == 0) {
      display.setCursor(0, 2);
      display.print(NoteValue[currentNoteKey]);
    }
    // rest of your code

Whatever the currentNoteKey value is, the correct NoteValue will be printed. Obviously you need to align the values in the array with the values currentNoteKey can get.

Similarly the next switch statement

      switch(currentScale) {
        case 1:
          display.print("Dor");
          break;
        case 2:
          display.print("Fri");
          break;
        case 3:
          display.print("LID");
          break;
        case 4:
          display.print("MIX");
          break;
        case 5:
        // etc etc

can be reduced to:

 
String ScaleValue[] = { "Dor", "Fri", "LID" }; // etc etc.
for(int i = 0; i < 8; i++) {
      // 
      display.print(ScaleValue[currentScale]);
      // rest of your code

I see that you are not using an interrupt to decode the rotary movement. Checking the encoder in the main loop is fast enough or do you experience that sometimes clicks are missed?

Ty for all the suggestions! I was using the loops as you suggested previously but I removed them because I read many places that using String variables wasnt a good idea because of memory allocation(im not a C programmer so have no idea if its true)?
Regarding the encoder interrupt, I havent really noticed any missed clicks tbh, would you happen to have a handy interrupt example?

zaphodb
New Member

Posts: 7

CV triggers to MIDI Feb 19, 2021 9:10:54 GMT laenan likes this

Quote

Post by zaphodb on Feb 19, 2021 9:10:54 GMT

using String variables wasnt a good idea because of memory allocation

There is a bit of truth to that but only if you assign something to a string and alter that string over time. Then new memory is allocated and the old memory is lost, and not available for new allocations unless a garbage collection is done. But if you assign only once (if e.g. you define them in a global variable), the memory is allocated only once and you can reference their values as often as you like without a memory penalty / this costing extra memory.

would you happen to have a handy interrupt example?

My question about the timer interrupt was not meant as a recommendation. If your encoder responds as expected then I would not switch to an interrupt implementation, especially because interrupts can interfere with using another device such as a display (because its driver might rely on an interrupt) and getting them to work in conjunction properly can prove to be complicated. I posed the question because I was hoping to find a solution for that.

Last Edit: Feb 19, 2021 9:33:51 GMT by zaphodb

Post by sleeptotem on Feb 4, 2021 21:51:28 GMT

Post by cpruby on Feb 5, 2021 3:31:20 GMT

Post by pt3r on Feb 5, 2021 7:47:19 GMT

Post by sleeptotem on Feb 5, 2021 8:49:13 GMT

Post by sleeptotem on Feb 5, 2021 8:58:18 GMT

Post by sleeptotem on Feb 10, 2021 12:45:03 GMT

Post by rodney on Feb 11, 2021 21:44:52 GMT

Post by zaphodb on Feb 14, 2021 15:16:35 GMT

Post by sleeptotem on Feb 16, 2021 9:30:28 GMT

Post by zaphodb on Feb 19, 2021 9:10:54 GMT